ECHO OFF
CLS
ECHO.
ECHO.
ECHO             *****************************************************
ECHO             *     WELCOME TO THE SOD INSTALLATION PROGRAM       *
ECHO             *          SOD SOFTWARE WAS PRODUCED BY             *
ECHO             *                                                   *
ECHO             *      CENTER FOR ADVANCED SPATIAL TECHNOLOGIES     *
ECHO             *              UNIVERSITY OF ARKANSAS               *
ECHO             *                  12 OZARK HALL                    *
ECHO             *              FAYETTEVILLE, ARKANSAS               *
ECHO             *                  501-575-6159                     *
ECHO             *                                                   *
ECHO             * WITH SUPPORT FROM THE NATIONAL SCIENCE FOUNDATION *
ECHO             *****************************************************
PAUSE
CLS
REM ***************************************************************
REM ***CHECK FOR A FILE ON FLOPPY TO BE SURE CORRECT DISK
REM ***IF THERE IS NO FILE CANCEL INSTALLATION
REM ***IF FILE IS THERE START INSTALLATION
REM ***************************************************************
IF NOT EXIST SODKIT.ZIP GOTO NOFILE
GOTO INSTIT
:NOFILE
ECHO.
ECHO.
ECHO.
ECHO     ERROR READING PROGRAM FILES!
ECHO     RESTART THE INSTALLATION PROGRAM AS FOLLOWS:
ECHO      1. PLACE THE INSTALLATION DISK #1 IN THE DISK DRIVE.
ECHO      2. TYPE THE DISK DRIVE LETTER PLUS A ":" THEN [ENTER]
ECHO      3. TYPE INSTALL [ENTER]
ECHO.
ECHO.
ECHO     PROGRAM WILL TERMINATE WHEN YOU PRESS [ENTER]
PAUSE
GOTO CANIT
REM **************************************************************
REM ***START INSTALLATION BY SETTING UP DEFAULT DESTINATION
REM ***AN CHECKING IF THE DIRECTORY EXIST
REM **************************************************************
:INSTIT
SET BONEDIR=\SOD
SET BONEDRI=C:
IF EXIST %BONEDRI%%BONEDIR%\NUL GOTO ISDIR
GOTO NODIR
REM **************************************************************
REM ***IF THE DEFAULT DIRECTORY EXIST GIVE USER THE OPTIONS TO
REM ***INSTALL IN DEFAULT OR USE DIFFERENT DIRECTORY OR QUIT
REM **************************************************************
:ISDIR
CLS
ECHO.
ECHO.
ECHO     THE SOD DEFAULT DIRECTORY %BONEDRI%%BONEDIR% EXIST.
ECHO     CHOOSE ONE OF THE FOLLOWING OPTIONS:
ECHO.
ECHO      1. INSTALL SOD SOFTWARE IN %BONEDRI%%BONEDIR% 
ECHO      2. CHOOSE A NEW DRIVE AND/OR DIRECTORY FOR INSTALLATION
ECHO      3. CANCEL INSTALLATION
ECHO.
ECHO.
BATCMD GN Enter a number 1-3:
IF ERRORLEVEL 4 GOTO INVALIS
IF ERRORLEVEL 3 GOTO CANIT
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 GOTO GETDRIVE
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 GOTO OKINST
GOTO INVALIS
:INVALIS
ECHO INVALID MENU CHOICE!
PAUSE
GOTO ISDIR
REM **************************************************************
REM ***CHOOSE NEW DRIVE AND SET BONEDRI
REM **************************************************************
:GETDRIVE
CLS
ECHO.
ECHO.
BATCMD GF AaBbCcDdEeFfGg Enter a new disk drive letter A-G:
IF ERRORLEVEL 13 GOTO SETG
IF ERRORLEVEL 11 GOTO SETF
IF ERRORLEVEL 9 GOTO SETE
IF ERRORLEVEL 7 GOTO SETD
IF ERRORLEVEL 5 GOTO SETC
IF ERRORLEVEL 3 GOTO SETB
IF ERRORLEVEL 1 GOTO SETA
GOTO GETDIR
:SETG
SET BONEDRI=G:
GOTO GETDIR
:SETF
SET BONEDRI=F:
GOTO GETDIR
:SETE
SET BONEDRI=E:
GOTO GETDIR
:SETD
SET BONEDRI=D:
GOTO GETDIR
:SETC
SET BONEDRI=C:
GOTO GETDIR
:SETB
SET BONEDRI=B:
GOTO GETDIR
:SETA
SET BONEDRI=A:
GOTO GETDIR
REM **************************************************************
REM ***CHOOSE A NEW DIRECTORY   DEFAULT = SOD AND SET BONEDIR
REM **************************************************************
:GETDIR
BATCMD GE Enter a new directory name [\SOD]:
SET BONEDIR=%BATCMD%
IF (%BATCMD%)==() SET BONEDIR=\SOD
ECHO.
ECHO YOUR NEW INSTALLATION DRIVE IS %BONEDRI%
ECHO YOUR NEW INSTALLATION DIRECTORY IS %BONEDIR%
ECHO.
BATCMD YN IS THE NEW DRIVE AND DIRECTORY CORRECT?[Y/N]
IF ERRORLEVEL 1 GOTO OKINST
GOTO GETDRIVE
REM **************************************************************
REM ***OK TO START INSTALLING FILES BUT FIRST CHECK IF THE 
REM ***DIRECTORIES ARE THERE AND MAKE THEM IF NEEDED
REM **************************************************************
:OKINST
CLS
ECHO.
ECHO           ******************************************************
ECHO           *       STARTING INSTALLATION.  PLEASE WAIT!         *
ECHO           ******************************************************
IF NOT EXIST %BONEDRI%%BONEDIR%\NUL MD %BONEDRI%%BONEDIR%
PKUNZIP -d SODKIT.ZIP %BONEDRI%%BONEDIR%
GOTO OKINST2
:OKINST2
CLS
ECHO.
ECHO           ******************************************************
ECHO           *       PLEASE INSERT SOD INSTALLATION DISK # 2      *
ECHO           ******************************************************
PAUSE
IF NOT EXIST FOXKIT.ZIP GOTO NOFOX
GOTO INSTFOX
:NOFOX
ECHO.
ECHO.
ECHO.
ECHO     ERROR READING PROGRAM FILES!
ECHO     INSERT DISK #2
ECHO.
ECHO.
PAUSE
GOTO OKINST2
:INSTFOX
CLS
ECHO.
ECHO           ******************************************************
ECHO           *       CONTINUING INSTALLATION.  PLEASE WAIT!         *
ECHO           ******************************************************
IF NOT EXIST %BONEDRI%%BONEDIR%\NUL MD %BONEDRI%%BONEDIR%
PKUNZIP FOXKIT.ZIP %BONEDRI%%BONEDIR%
CLS
ECHO INSTALLATION COMPLETE.
ECHO TO RUN SOD: CHANGE DIRECTORY TO %BONEDRI%%BONEDIR%
ECHO               TYPE SOD [ENTER]
PAUSE
GOTO THEEND
REM ************************************************************
REM ***THERE IS NO DEFAULT DIRECTORY ON THE HARD DISK SO
REM ***GIVE OPTIONS TO GO AHEAD AND INSTALL THERE OR PUT
REM ***STUFF SOMEWHERE ELSE
REM ************************************************************
:NODIR
CLS
ECHO.
ECHO.
ECHO     THE SOD DEFAULT DIRECTORY IS %BONEDRI%%BONEDIR% 
ECHO     CHOOSE ONE OF THE FOLLOWING OPTIONS:
ECHO.
ECHO      1. INSTALL SOD SOFTWARE IN %BONEDRI%%BONEDIR% 
ECHO      2. CHOOSE A NEW DRIVE AND/OR DIRECTORY FOR INSTALLATION
ECHO      3. CANCEL INSTALLATION
ECHO.
ECHO.
BATCMD GN Enter a number 1-3:
IF ERRORLEVEL 4 GOTO INVALID
IF ERRORLEVEL 3 GOTO CANIT
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 GOTO GETDRIVE
IF ERRORLEVEL 1 IF NOT ERRORLEVEL 2 GOTO OKINST
GOTO INVALID
:INVALID
ECHO INVALID MENU CHOICE!
PAUSE
GOTO NODIR
:CANIT
CLS
ECHO.
ECHO CANCELING SOD INSTALLATION.
GOTO THEEND
:THEEND
CLS
%BONEDRI%
CD %BONEDIR%
ECHO ON